# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=pbr
PYTHON_COMPAT=( python3_{13..14} )

inherit distutils-r1 pypi

DESCRIPTION="Command Line Interface Formulation Framework"
HOMEPAGE="
	https://opendev.org/openstack/cliff/
	https://github.com/openstack/cliff/
	https://pypi.org/project/cliff/
"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~mips ~ppc64 ~riscv ~s390 x86"

RDEPEND="
	>=dev-python/autopage-0.4.0[${PYTHON_USEDEP}]
	>=dev-python/cmd2-4.0.0[${PYTHON_USEDEP}]
	dev-python/prettytable[${PYTHON_USEDEP}]
	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
	>=dev-python/pyyaml-3.12.0[${PYTHON_USEDEP}]
	>=dev-python/stevedore-5.6.0[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
		$(python_gen_cond_dep '
			>=dev-python/sphinx-5.0.0[${PYTHON_USEDEP}]
		' 3.{13..15})
		>=dev-python/testtools-2.8.0[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

python_test() {
	local -x COLUMNS=80

	local EPYTEST_IGNORE=()
	if ! has_version "dev-python/sphinx[${PYTHON_USEDEP}]"; then
		EPYTEST_IGNORE+=( cliff/tests/test_sphinxext.py )
	fi

	epytest
}