# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

# 1.1.3: first release cut from Git, tag v1.1.3 of https://git.hedronfire.com/live-wallpaper (crucible distfiles); no patches.
EAPI=8
inherit meson

DESCRIPTION="Animated Wayfire wallpapers: Hyperspace, Nebula and Digital Rain"
HOMEPAGE="https://www.hedronfire.com/"
SRC_URI="https://www.hedronfire.com/distfiles/${P}.tar.gz"
LICENSE="MIT"
# The subslot follows the liblive-wallpaper-render.so ABI.
SLOT="0/2"
KEYWORDS="~amd64"
# The GPU tests need a private headless Wayfire session; see README.md.
RESTRICT="mirror test"

BDEPEND="virtual/pkgconfig"
DEPEND="
	dev-libs/json-c:=
	>=gui-wm/wayfire-0.11.0-r60:0=
	gui-libs/wf-config:=
	gui-libs/wlroots:0.20=
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/glm
	media-libs/mesa[gles2(+)]
"
# Digital Rain draws katakana from Noto Sans CJK (fontconfig fallback).
RDEPEND="
	${DEPEND}
	media-fonts/noto-cjk
"

src_install() {
	meson_src_install
	# meson installs package docs under ${PN}; Gentoo keeps them under ${PF}.
	if [[ -d ${ED}/usr/share/doc/${PN} ]]; then
		mkdir -p "${ED}/usr/share/doc/${PF}" || die
		mv "${ED}/usr/share/doc/${PN}"/* "${ED}/usr/share/doc/${PF}/" || die
		rmdir "${ED}/usr/share/doc/${PN}" || die
	fi
	dodoc README.md render/nebula/UPSTREAM render/nebula/LICENSE
}

pkg_postinst() {
	elog "WCM → Desktop → Live Wallpaper holds the effect and background settings;"
	elog "<super> <alt> B pauses and resumes the animation."
}