# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
inherit meson

DESCRIPTION="Independent custom Wayfire plugins for window actions, Show Desktop, workspace backgrounds and the screensaver"
HOMEPAGE="https://www.hedronfire.com/"
SRC_URI="https://www.hedronfire.com/distfiles/wayfire-plugins-custom-0.1.0-r20.tar.xz"
S="${WORKDIR}/wayfire-plugins-custom-0.1.0-r20"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+window-actions +panel-desktop +workspace-backgrounds +screensaver test"
REQUIRED_USE="|| ( window-actions panel-desktop workspace-backgrounds screensaver )"
RESTRICT="mirror !test? ( test )"

RDEPEND="
	>=gui-wm/wayfire-0.11.0-r19:0=
	gui-libs/wf-config:=
	gui-libs/wlroots:0.20=
	workspace-backgrounds? ( >=gui-wm/wayfire-0.11.0-r29:0= x11-libs/cairo x11-libs/gdk-pixbuf:2 )
	screensaver? ( >=gui-wm/wayfire-0.11.0-r73:0= )
	!<gui-apps/wayfire-panel-0.1.0-r7
	!<gui-apps/wayfire-dock-0.1.1-r5
	!<gui-apps/wayfire-settings-0.1.4-r3
	!<gui-apps/wayfire-session-0.1.11-r3
"
DEPEND="${RDEPEND}
	workspace-backgrounds? ( dev-cpp/nlohmann_json )
	window-actions? ( dev-cpp/nlohmann_json )
"
BDEPEND="virtual/pkgconfig"

src_configure() {
	local emesonargs=(
		$(meson_use window-actions)
		$(meson_use panel-desktop)
		$(meson_use workspace-backgrounds)
		$(meson_use screensaver)
		-Dworkspace-backgrounds-test-api=false
		$(meson_use test tests)
	)
	meson_src_configure
}

src_install() {
	meson_src_install
	# meson installs package docs under ${PN}; Gentoo keeps them under ${PF}.
	if [[ -d ${ED}/usr/share/doc/${PN} ]]; then
		mkdir -p "${ED}/usr/share/doc/${PF}" || die
		mv "${ED}/usr/share/doc/${PN}"/* "${ED}/usr/share/doc/${PF}/" || die
		rmdir "${ED}/usr/share/doc/${PN}" || die
	fi
	dodoc README.md ORIGINS.json
	local plugin
	for plugin in window-actions panel-desktop workspace-backgrounds screensaver; do
		if use "${plugin}"; then
			docinto "plugins/${plugin}"
			dodoc "plugins/${plugin}/README.md" "plugins/${plugin}/LICENSE"
		fi
	done
}

pkg_postinst() {
	elog "Workspace backgrounds: start the matching Wayfire, enable workspace-backgrounds and ipc, then open WCM Displays → Backgrounds."
	elog "Load plugins by bare name; versioned library paths are no longer installed."
	elog "Select modules with USE flags; enable them separately in Wayfire. Drag snapping is configured in Move."
	if use screensaver; then
		elog "Screensaver: add screensaver to [core] plugins (/usr/libexec/live-wallpaper/migrate"
		elog "does this when coming from ambient-background). Settings: WCM -> Screensaver."
	fi
	if use window-actions; then
		elog "The window-state plugin is now window-actions (libwindow-actions.so). In wayfire.ini,"
		elog "replace window-state with window-actions in [core] plugins and delete any"
		elog "[window-state] section, then log out and back in so the panel, dock and session"
		elog "daemon reconnect. Activity placements now live in the session daemon's"
		elog "activities.json; ~/.local/state/wayfire/layouts.db* is no longer used and can be deleted."
	fi
}