blob: 3cf578d7bf180c54c5e1636dcb13661fff1f3a08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{13..14} )
inherit distutils-r1 pypi
DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
HOMEPAGE="
https://github.com/celery/py-amqp/
https://pypi.org/project/amqp/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="extras"
RDEPEND="
>=dev-python/vine-5.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
net-misc/rabbitmq-server
)
"
distutils_enable_sphinx docs \
'>=dev-python/sphinx-celery-2.1.3'
EPYTEST_PLUGINS=( pytest-rerunfailures )
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# fails when gssapi is installed (how does that test make sense?!)
t/unit/test_sasl.py::test_SASL::test_gssapi_missing
)
src_test() {
einfo "Starting rabbitmq"
# TODO: enable TLS?
local -x RABBITMQ_LOG_BASE="${T}/rabbitmq/log"
local -x RABBITMQ_MNESIA_BASE="${T}/rabbitmq/mnesia"
local -x RABBITMQ_LOGS="${T}/rabbitmq.log"
local -x RABBITMQ_PID_FILE="${T}/rabbitmq.pid"
local -x RABBITMQ_ENABLED_PLUGINS_FILE="${T}/rabbitmq/enabled_plugins"
/usr/libexec/rabbitmq/rabbitmq-server -p 5672:5672 &
einfo "Waiting for rabbitmq to fully load"
local i
for (( i = 0; i < 60; i++ )); do
{ echo >/dev/tcp/localhost/5672 ; } &> /dev/null && break
sleep 1
done
[[ ${i} -lt 60 ]] || die "rabbitmq failed to start within 60 seconds"
einfo "rabbitmq is ready"
distutils-r1_src_test
einfo "Stopping rabbitmq"
kill "$(<"${RABBITMQ_PID_FILE}")" || die
}
python_test() {
epytest -k "not tls"
}
python_install_all() {
if use extras; then
insinto /usr/share/${PF}/extras
doins -r extra
fi
distutils-r1_python_install_all
}
|
