blob: df5310b5f2fc7fab223031320832d52607975a1e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
|
# Copyright 2021-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic xdg optfeature
ASMJIT_COMMIT="416f7356967c1f66784dc1580fe157f9406d8bff" # master~71
GLSLANG_COMMIT="f0bd0257c308b9a26562c1a30c4748a0219cc951" # tags/16.2.0
WOLFSSL_COMMIT="3c5eead44904df64e6a5a1f4ebdce377d35a849a" # tags/5.9.4-stable
SOUNDTOUCH_COMMIT="a0fba77b6f9cfbdb71f8bbec58b6ac4e5e3b1097" # head
YAMLCPP_COMMIT="51a5d623e3fde1f58829a56ba910f1cb33596222" # master
FUSION_COMMIT="9325424011892abacc0ce42b8bb1a8ae20264b9b" # tags/1.3.3
VULKANMEMORYALLOCATOR_COMMIT="3aa921224c154a0d2c43912bc88e1c42ce1f7607" # tags/3.4.0
GAMEMODE_COMMIT="c54d6d4243b0dd0afcb49f2c9836d432da171a2b" # tags/1.8.2
DESCRIPTION="PS3 emulator/debugger"
HOMEPAGE="https://rpcs3.net/"
if [[ ${PV} == "9999" ]]; then
EGIT_REPO_URI="https://github.com/RPCS3/rpcs3"
EGIT_SUBMODULES=(
'asmjit' '3rdparty/glslang' '3rdparty/wolfssl'
'3rdparty/SoundTouch/soundtouch' '3rdparty/fusion/fusion' '3rdparty/GPUOpen/VulkanMemoryAllocator'
'3rdparty/feralinteractive/feralinteractive' '3rdparty/yaml-cpp'
)
inherit git-r3
else
SRC_URI="
https://github.com/RPCS3/rpcs3/archive/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/asmjit/asmjit/archive/${ASMJIT_COMMIT}.tar.gz -> ${PN}-asmjit-${ASMJIT_COMMIT}.tar.gz
https://github.com/KhronosGroup/glslang/archive/${GLSLANG_COMMIT}.tar.gz -> ${PN}-glslang-${GLSLANG_COMMIT}.tar.gz
https://github.com/wolfSSL/wolfssl/archive/${WOLFSSL_COMMIT}.tar.gz -> ${PN}-wolfssl-${WOLFSSL_COMMIT}.tar.gz
https://github.com/RPCS3/soundtouch/archive/${SOUNDTOUCH_COMMIT}.tar.gz
-> ${PN}-soundtouch-${SOUNDTOUCH_COMMIT}.tar.gz
https://github.com/RPCS3/yaml-cpp/archive/${YAMLCPP_COMMIT}.tar.gz -> ${PN}-yaml-cpp-${YAMLCPP_COMMIT}-.tar.gz
https://github.com/xioTechnologies/Fusion/archive/${FUSION_COMMIT}.tar.gz -> ${PN}-fusion-${FUSION_COMMIT}.tar.gz
https://github.com/GPUOpen-LibrariesAndSDKs/VulkanMemoryAllocator/archive/${VULKANMEMORYALLOCATOR_COMMIT}.tar.gz
-> ${PN}-VulkanMemoryAllocator-${VULKANMEMORYALLOCATOR_COMMIT}.tar.gz
https://github.com/FeralInteractive/gamemode/archive/${GAMEMODE_COMMIT}.tar.gz -> ${PN}-GameMode.tar.gz
"
KEYWORDS="~amd64"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="discord faudio +llvm opencv vulkan X wayland"
DEPEND="
app-arch/7zip
app-arch/zstd
>=dev-libs/protobuf-33.0.0
dev-libs/hidapi
dev-libs/libevdev
dev-libs/pugixml
dev-libs/stb
dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
dev-qt/qtmultimedia:6
dev-qt/qtsvg:6
media-libs/alsa-lib
media-libs/cubeb
media-libs/glew
media-libs/libglvnd
media-libs/libpng:=
media-libs/openal
media-libs/rtmidi
media-libs/libsdl3[opengl,vulkan?,X?,wayland?]
media-video/ffmpeg:=
net-libs/miniupnpc:=
net-misc/curl
llvm-core/llvm:=
virtual/zlib:=
virtual/libusb:1
x11-libs/libX11
faudio? ( app-emulation/faudio )
opencv? ( media-libs/opencv )
vulkan? ( media-libs/vulkan-loader[wayland?] )
wayland? ( dev-libs/wayland )
"
RDEPEND="${DEPEND}"
QA_PREBUILT="usr/share/rpcs3/test/.*"
QA_WX_LOAD="usr/share/rpcs3/test/*"
PATCHES=(
"${FILESDIR}/${PN}-system-stb.patch"
)
src_prepare() {
if [[ ${PV} != "9999" ]]; then
rmdir "${S}/3rdparty/asmjit/asmjit" || die
mv "${WORKDIR}/asmjit-${ASMJIT_COMMIT}" "${S}/3rdparty/asmjit/asmjit" || die
rmdir "${S}/3rdparty/glslang/glslang" || die
mv "${WORKDIR}/glslang-${GLSLANG_COMMIT}" "${S}/3rdparty/glslang/glslang" || die
rmdir "${S}/3rdparty/wolfssl/wolfssl" || die
mv "${WORKDIR}/wolfssl-${WOLFSSL_COMMIT}" "${S}/3rdparty/wolfssl/wolfssl" || die
rmdir "${S}/3rdparty/SoundTouch/soundtouch" || die
mv "${WORKDIR}/soundtouch-${SOUNDTOUCH_COMMIT}" "${S}/3rdparty/SoundTouch/soundtouch" || die
rmdir "${S}/3rdparty/yaml-cpp/yaml-cpp" || die
mv "${WORKDIR}/yaml-cpp-${YAMLCPP_COMMIT}" "${S}/3rdparty/yaml-cpp/yaml-cpp" || die
rmdir "${S}/3rdparty/fusion/fusion" || die
mv "${WORKDIR}/Fusion-${FUSION_COMMIT}" "${S}/3rdparty/fusion/fusion" || die
rmdir "${S}/3rdparty/GPUOpen/VulkanMemoryAllocator" || die
mv "${WORKDIR}/VulkanMemoryAllocator-${VULKANMEMORYALLOCATOR_COMMIT}" \
"${S}/3rdparty/GPUOpen/VulkanMemoryAllocator" || die
rmdir "${S}/3rdparty/feralinteractive/feralinteractive" || die
mv "${WORKDIR}/gamemode-${GAMEMODE_COMMIT}" \
"${S}/3rdparty/feralinteractive/feralinteractive" || die
#Define RPCS3 Version
{ echo "#define RPCS3_GIT_VERSION \"${PV}\""
echo '#define RPCS3_GIT_BRANCH "master"'
echo '#define RPCS3_GIT_FULL_BRANCH "RPCS3/rpcs3/master"'
echo '#define RPCS3_GIT_VERSION_NO_UPDATE 1'; } > rpcs3/git-version.h
fi
# Disable automagic ccache
sed -i -e '/find_program(CCACHE_PATH ccache .*)/d' CMakeLists.txt || die
# QA Notice: Compatibility with CMake < 3.5 has been removed from CMake 4
find . -maxdepth 9 -type f -name CMakeLists.txt \
-exec sed -i -e '/cmake_minimum_required/c\cmake_minimum_required(VERSION 4.0)' {} \; \
|| die "Could not update cmake_minimum_required"
# Unbundle yaml-cpp: system yaml-cpp should be compiled with -fexceptions
# sed -i -e '/yaml-cpp/d' 3rdparty/CMakeLists.txt || die
# sed -i -e '$afind_package(yaml-cpp)\n' CMakeLists.txt || die
# sed -i -e 's/3rdparty::yaml-cpp/yaml-cpp/' rpcs3/Emu/CMakeLists.txt \
# rpcs3/rpcs3qt/CMakeLists.txt || die
cmake_src_prepare
}
src_configure() {
filter-lto
local mycmakeargs=(
-DBUILD_SHARED_LIBS=OFF # to remove after unbundling
-DUSE_PRECOMPILED_HEADERS=ON
-DUSE_SYSTEM_CUBEB=ON
-DUSE_SYSTEM_CURL=ON
-DUSE_SYSTEM_FFMPEG=ON
-DUSE_SYSTEM_PROTOBUF=ON
-DUSE_SYSTEM_HIDAPI=ON
-DUSE_SYSTEM_LIBPNG=ON
-DUSE_SYSTEM_LIBUSB=ON
-DUSE_SYSTEM_MINIUPNPC=ON
-DUSE_SYSTEM_PUGIXML=ON
-DUSE_SYSTEM_RTMIDI=ON
-DUSE_SYSTEM_ZLIB=ON
-DUSE_SYSTEM_ZSTD=ON
-DUSE_DISCORD_RPC=$(usex discord)
-DUSE_FAUDIO=$(usex faudio)
-DUSE_SYSTEM_OPENCV=$(usex opencv)
-DUSE_VULKAN=$(usex vulkan)
-DWITH_LLVM=$(usex llvm)
$(cmake_use_find_package wayland Wayland)
)
# These options are defined conditionally to suppress QA notice
use faudio && mycmakeargs+=( -DUSE_SYSTEM_FAUDIO=$(usex faudio) )
cmake_src_configure
sed -i -e 's/FFMPEG_LIB_AVFORMAT-NOTFOUND/avformat/' -e 's/FFMPEG_LIB_AVCODEC-NOTFOUND/avcodec/' \
-e 's/FFMPEG_LIB_AVUTIL-NOTFOUND/avutil/' -e 's/FFMPEG_LIB_SWSCALE-NOTFOUND/swscale/' \
-e 's/FFMPEG_LIB_SWRESAMPLE-NOTFOUND/swresample/' "${BUILD_DIR}"/build.ninja || die
}
src_install() {
cmake_src_install
# remove unneccessary files to save some space
rm -rf "${ED}/usr/share/rpcs3/"{git,test} || die
}
pkg_postinst() {
optfeature "FeralInteractive GameMode support" games-util/gamemode
}
|
