blob: 5a708aca72b783b0d9345c0c423e14d408efe148 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
inherit autotools flag-o-matic prefix python-any-r1 xdg
DESCRIPTION="A Doom source port that is minimalist and historically accurate"
HOMEPAGE="https://www.chocolate-doom.org"
SRC_URI="https://github.com/${PN}/${PN}/archive/${P}.tar.gz"
S="${WORKDIR}/${PN}-${P}"
LICENSE="BSD GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
IUSE="doc fluidsynth libsamplerate +midi png vorbis"
DEPEND="
media-libs/libsdl2[video]
media-libs/sdl2-mixer[midi?,vorbis?]
media-libs/sdl2-net
fluidsynth? ( media-sound/fluidsynth:= )
libsamplerate? ( media-libs/libsamplerate )
png? ( media-libs/libpng:= )
"
RDEPEND="
${DEPEND}
"
# ${PYTHON_DEPS} for bash-completion and docs.
BDEPEND="
${PYTHON_DEPS}
"
DOCS=(
"AUTHORS"
"ChangeLog"
"NEWS.md"
"NOT-BUGS.md"
"PHILOSOPHY.md"
"README.md"
"README.Music.md"
"README.Strife.md"
)
src_prepare() {
default
hprefixify src/d_iwad.c
eautoreconf
}
src_configure() {
# -Werror=lto-type-mismatch
# https://bugs.gentoo.org/978909
# https://github.com/chocolate-doom/chocolate-doom/issues/1824
filter-lto
econf \
--enable-bash-completion \
$(use_enable doc) \
$(use_with fluidsynth) \
--disable-fonts \
--disable-icons \
$(use_with libsamplerate) \
$(use_with png libpng)
}
src_install() {
emake DESTDIR="${D}" install
# Remove redundant documentation files
rm -r "${ED}/usr/share/doc/"* || die
einstalldocs
}
|
