blob: faed92bd2355c4b4fff6535c1ceebdd8c3f6686d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{13..14} )
PYTHON_REQ_USE="xml(+)"
inherit meson gnome2-utils optfeature pax-utils python-single-r1 xdg
DESCRIPTION="A fork of GNOME Shell with layout similar to GNOME 2"
HOMEPAGE="https://linuxmint-developer-guide.readthedocs.io/en/latest/cinnamon.html https://linuxmint.com/"
SRC_URI="https://github.com/linuxmint/cinnamon/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD GPL-2+ GPL-3+ GPL-3-with-openssl-exception LGPL-2+ LGPL-2.1 LGPL-2.1+ MIT"
SLOT="0"
KEYWORDS="amd64 arm64 ~loong ~riscv x86"
IUSE="+eds +gstreamer gtk-doc +nls +networkmanager wayland"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DEPEND="
${PYTHON_DEPS}
>=app-accessibility/at-spi2-core-2.46.0:2
>=app-crypt/gcr-3.7.5:0/1
>=dev-libs/glib-2.79.2:2[dbus]
>=dev-libs/gobject-introspection-1.82.0-r2:=
dev-libs/libxml2:2=
>=gnome-extra/cinnamon-desktop-6.6:0=
>=gnome-extra/cinnamon-menus-6.6
>=gnome-extra/cjs-140[cairo(+)]
sys-apps/dbus
>=sys-auth/polkit-0.100[introspection]
virtual/opengl
x11-libs/cairo
x11-libs/gdk-pixbuf:2[introspection]
>=x11-libs/gtk+-3.12.0:3[introspection,wayland?,X]
>=x11-libs/libnotify-0.7.3:0=[introspection]
x11-libs/libX11
dev-util/glib-utils
x11-base/xorg-proto
>=x11-libs/libXfixes-5.0
x11-libs/pango[introspection]
>=x11-libs/xapp-3.2.2[introspection]
>=x11-wm/muffin-6.6[introspection,wayland?]
eds? (
gnome-extra/evolution-data-server
)
gstreamer? (
media-libs/gst-plugins-base:1.0
media-libs/gstreamer:1.0
)
networkmanager? (
>=app-crypt/libsecret-0.18
>=net-misc/networkmanager-1.10.4[introspection]
)
"
# libtimezonemap used by datetime settings
# iso-flag-png (unpackaged) used by keyboard layout settings
RDEPEND="
${DEPEND}
app-i18n/ibus[introspection]
dev-libs/keybinder:3[introspection]
dev-libs/libtimezonemap
$(python_gen_cond_dep '
dev-python/babel[${PYTHON_USEDEP}]
dev-python/distro[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/pycairo[${PYTHON_USEDEP}]
dev-python/pygobject:3[${PYTHON_USEDEP}]
dev-python/pyinotify[${PYTHON_USEDEP}]
dev-python/python-pam[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/setproctitle[${PYTHON_USEDEP}]
dev-python/tinycss2[${PYTHON_USEDEP}]
>=dev-python/python3-xapp-3.0.2[${PYTHON_USEDEP}]
')
>=gnome-base/dconf-0.4.1
>=gnome-base/gsettings-desktop-schemas-2.91.91
>=gnome-base/libgnomekbd-2.91.4
>=gnome-extra/cinnamon-control-center-6.6[networkmanager=,wayland?]
>=gnome-extra/cinnamon-screensaver-6.6
>=gnome-extra/cinnamon-session-6.6
>=gnome-extra/cinnamon-settings-daemon-6.6[wayland?]
>=gnome-extra/nemo-6.6[wayland?]
media-libs/graphene[introspection]
media-libs/gsound
net-libs/libsoup:3.0[introspection]
net-misc/wget
sys-apps/accountsservice[introspection]
sys-apps/coreutils
sys-apps/pciutils
sys-apps/util-linux
sys-apps/xdg-desktop-portal-gtk
sys-apps/xdg-desktop-portal-xapp
sys-power/upower[introspection]
x11-misc/xdg-utils
x11-themes/adwaita-icon-theme
x11-themes/gnome-themes-standard
x11-themes/xapp-symbolic-icon-theme
nls? (
>=gnome-extra/cinnamon-translations-6.6
)
networkmanager? (
net-libs/libnma[introspection]
)
"
BDEPEND="
dev-lang/sassc
>=sys-devel/gettext-0.17
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc )
"
PATCHES=(
# Fix backgrounds path as cinnamon doesn't provide them
# https://github.com/linuxmint/Cinnamon/issues/3575
"${FILESDIR}/${PN}-3.8.0-gnome-background-compatibility.patch"
# Use wheel group instead of sudo (from Fedora/Arch)
# https://github.com/linuxmint/Cinnamon/issues/3576
"${FILESDIR}/${PN}-3.6.6-wheel-sudo.patch"
# Fix crash when networkmanager is not present.
# https://github.com/linuxmint/cinnamon/pull/13651
"${FILESDIR}/${PN}-6.6.7-fix-disable-networkmanager.patch"
# Additional girepository-2.0 fixes.
# https://github.com/linuxmint/cinnamon/commit/3a2d558aa575f0ea364c5b4e30d2eb3ee604ee58
"${FILESDIR}/${PN}-6.6.8-fix-misc-util-gir-handling.patch"
)
src_prepare() {
default
# shebang fixing craziness
local p
for p in $(grep -rl '#!.*python3' || die); do
python_fix_shebang "${p}"
done
}
src_configure() {
local emesonargs=(
$(meson_use gstreamer build_recorder)
$(meson_use gtk-doc docs)
$(meson_use wayland)
-Dnm_agent=$(usex networkmanager internal disabled)
-Dpy3modules_dir="$(python_get_sitedir)"
)
meson_src_configure
}
src_install() {
meson_src_install
python_optimize "${D}$(python_get_sitedir)"
python_optimize "${ED}"/usr/share/cinnamon/
# Required for gnome-shell on hardened/PaX, bug #398941
pax-mark mr "${ED}"/usr/bin/cinnamon
# Doesn't exist by default
keepdir /etc/xdg/menus/applications-merged
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
if use gstreamer; then
if ! has_version 'media-libs/gst-plugins-good:1.0' || \
! has_version 'media-plugins/gst-plugins-vpx:1.0'; then
ewarn "To make use of Cinnamon's built-in screen recording utility,"
ewarn "you need to either install media-libs/gst-plugins-good:1.0"
ewarn "and media-plugins/gst-plugins-vpx:1.0, or use dconf-editor to change"
ewarn "org.cinnamon.recorder/pipeline to what you want to use."
fi
else
ewarn "Cinnamon's built-in screen recording utility is not installed"
ewarn "because gstreamer support is disabled."
fi
optfeature "Thunderbolt security management in System Settings" sys-apps/bolt
optfeature "additional hardware information in System Settings" sys-apps/inxi
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
