blob: 52da83612c98806ff14b61865e3153f3e130f04c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 2025-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_EXAMPLES="true"
ECM_TEST="true"
KFMIN=6.30.0
QTMIN=6.11.2
inherit ecm plasma.kde.org
DESCRIPTION="Style engine providing a unified style description to separate output styles"
HOMEPAGE="https://quantumproductions.info/articles/2025-02/moving-kdes-styling-future"
LICENSE="|| ( LGPL-2.1 LGPL-3 ) GPL-3 BSD-2"
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="doc tools +widgets"
# IUSE="svg"
# svg? (
# >=dev-cpp/rapidyaml-0.7.2:=
# >=dev-qt/qtsvg-${QTMIN}:6
# >=kde-frameworks/karchive-${KFMIN}:6
# >=kde-frameworks/kcolorscheme-${KFMIN}:6
# >=kde-frameworks/kconfig-${KFMIN}:6
# kde-plasma/libplasma:6=
# )
DEPEND="
>=dev-libs/cxx-rust-cssparser-1.1.0
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets?]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=dev-qt/qtshadertools-${QTMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kirigami-${KFMIN}:6
tools? ( virtual/zlib:= )
"
RDEPEND="${DEPEND}"
BDEPEND="
doc? ( >=dev-qt/qttools-${QTMIN}:6[qdoc] )
"
DOCS=( README.md )
src_prepare() {
if ! use doc ; then
# Avoid automagic qttools[qdoc] dep
sed -i -e '/include(ECMGenerateQDoc)/d' CMakeLists.txt || die
sed -i -e '/ecm_generate_qdoc/d' src/CMakeLists.txt || die
fi
ecm_src_prepare
}
src_configure() {
local mycmakeargs=(
-DBUILD_INPUT_PLASMASVG=OFF # defunct as of 2025-10-09
-DBUILD_INPUT_CSS=ON # CSS is the default input format
-DBUILD_WITH_KDEFRAMEWORKS=ON # required by BUILD_PLATFORM_PLASMA
-DBUILD_PLATFORM_PLASMA=ON
-DBUILD_OUTPUT_KIRIGAMI=ON
-DBUILD_OUTPUT_QTQUICK=ON # required by BUILD_OUTPUT_KIRIGAMI
-DBUILD_OUTPUT_QTWIDGETS=$(usex widgets)
-DBUILD_TOOLS=$(usex tools)
)
ecm_src_configure
}
src_install() {
use examples && local DOCS+=( "${S}"/examples/snippets/{Button,Positioner}.qml )
use tools && dobin "${BUILD_DIR}"/bin/union-ruleinspector
ecm_src_install
}
|
