blob: 0cd51271fbc2ba9ff12a3204b6fd6e9490769df4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
VALA_MIN_API_VERSION="0.56"
inherit gnome2-utils meson vala virtualx xdg
DESCRIPTION="Email client for GNOME, forked from Geary"
HOMEPAGE="https://gitlab.gnome.org/donnybeelo/convey"
SRC_URI="https://gitlab.gnome.org/donnybeelo/convey/-/archive/${PV}/${P}.tar.bz2"
# LGPL-2.1+ for the code (COPYING), CC-BY-3.0 for the icons (COPYING.icons),
# CC-BY-SA-3.0 for the sound (COPYING.sounds), MIT for the bundled ui/darkreader.js
LICENSE="LGPL-2.1+ CC-BY-3.0 CC-BY-SA-3.0 MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="+libunwind test +tnef"
RESTRICT="!test? ( test )"
RDEPEND="
>=app-crypt/gcr-4:4[gtk,vala]
>=app-crypt/libsecret-0.11[vala]
>=app-text/enchant-2.1:2
app-text/iso-codes
>=dev-db/sqlite-3.24:3
dev-libs/folks:=
>=dev-libs/glib-2.80:2
>=dev-libs/gmime-3.2.4:3.0[vala]
dev-libs/icu:=
>=dev-libs/json-glib-1.0
>=dev-libs/libgee-0.8.5:0.8
dev-libs/libpeas:2[vala]
dev-libs/libxml2:=
dev-libs/snowball-stemmer:=
>=gui-libs/gtk-4.16.0:4
>=gui-libs/libadwaita-1.7:1[vala]
media-libs/gst-plugins-bad:1.0
media-libs/gst-plugins-base:1.0
media-libs/gstreamer:1.0
net-libs/gnome-online-accounts:=[vala]
net-libs/libsoup:3.0[vala]
net-libs/webkit-gtk:6=
x11-libs/cairo
libunwind? ( sys-libs/libunwind:= )
tnef? ( >=net-mail/ytnef-1.9.3 )
"
DEPEND="${RDEPEND}"
BDEPEND="
$(vala_depend)
dev-libs/appstream
dev-util/desktop-file-utils
dev-util/glib-utils
dev-util/itstool
sys-devel/gettext
virtual/pkgconfig
test? ( net-libs/gnutls[tools] )
"
src_prepare() {
vala_setup
default
}
src_configure() {
local emesonargs=(
-Dprofile=release
-Drevno="${PV}"
-Dvaladoc=disabled
-Dcontractor=disabled
$(meson_feature libunwind)
$(meson_feature tnef)
)
meson_src_configure
}
src_test() {
# WebKitGTK's bubblewrap sandbox cannot create user namespaces
# inside Portage's sandbox
local -x WEBKIT_DISABLE_SANDBOX_THIS_IS_DANGEROUS=1
virtx meson_src_test
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
