blob: 8aaa027876937a25afbc07febc851cfeded06566 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop qmake-utils xdg
DESCRIPTION="Qt client for the music player daemon (MPD)"
HOMEPAGE="https://quimup.sourceforge.io"
SRC_URI="https://sourceforge.net/projects/quimup/files/${PN^}%20${PV}/${P/-/_}_source.tar.gz"
S="${WORKDIR}/${P/-/_}_source"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
DEPEND="
dev-qt/qtbase:6[gui,network,widgets]
media-libs/libmpdclient
"
RDEPEND="
${DEPEND}
dev-qt/qtsvg:6
"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-2.1.2-clang.patch
)
# bug 947318
DOCS=( RPM_DEB_build/share/doc/quimup/{changelog,faq,readme} )
src_prepare() {
default
# cleanup sources
rm -r build .qmake.stash Makefile || die
}
src_configure() {
eqmake6
}
src_install() {
default
dobin ${PN}
local x
for x in 32 64 128 scalable; do
doicon -s ${x} RPM_DEB_build/share/icons/hicolor/${x}*/*
done
domenu RPM_DEB_build/share/applications/${PN^}.desktop
}
|
