blob: 6a900a937d9cc5639c6b1c8b95e41d690475c8f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs verify-sig
MY_P="openssh-${PV/_p/p}"
DESCRIPTION="GTK-based passphrase dialog for use with OpenSSH"
HOMEPAGE="https://www.openssh.org/"
SRC_URI="
mirror://openbsd/OpenSSH/portable/${MY_P}.tar.gz
verify-sig? ( mirror://openbsd/OpenSSH/portable/${MY_P}.tar.gz.asc )
"
S="${WORKDIR}/${MY_P}/contrib"
LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="gtk4"
RESTRICT="test"
RDEPEND="
app-accessibility/at-spi2-core
media-libs/harfbuzz
x11-libs/cairo
x11-libs/gdk-pixbuf
x11-libs/libX11
x11-libs/pango
dev-libs/glib:2
gtk4? (
app-crypt/gcr:4
gui-libs/gtk:4
)
!gtk4? ( x11-libs/gtk+:3[X] )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
verify-sig? ( sec-keys/openpgp-keys-openssh )
"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/openssh.org.asc"
src_unpack() {
default
# We don't have signatures for HPN, X509, so we have to write this ourselves
use verify-sig && \
verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.gz{,.asc}
}
src_prepare() {
default
# Upstream does not set LDFLAGS, so we do it ourselves.
sed -i -e 's|\$(CC) \$(CFLAGS)|\$(CC) \$(CFLAGS) \$(LDFLAGS)|' Makefile \
|| die "Could not set LDFLAGS"
}
src_configure() {
tc-export CC
}
src_compile() {
if use gtk4; then
emake gnome-ssh-askpass4
else
emake gnome-ssh-askpass3
fi
}
src_install() {
if use gtk4; then
local GNOME_SSH_ASKPASS="gnome-ssh-askpass4"
else
local GNOME_SSH_ASKPASS="gnome-ssh-askpass3"
fi
dobin "${GNOME_SSH_ASKPASS}";
newenvd - 99gnome_ssh_askpass <<-EOF
export SSH_ASKPASS='${EPREFIX}/usr/bin/${GNOME_SSH_ASKPASS}'
EOF
}
|
